Sync On:Sync Rate 0:Autocam Off

Global Limbcount as Integer


Make_Branch(1)
Position Object 1,0,-8,25

For i = 1 to 3
   Fractal_Limb(1,0,0)
Next i

Leaves(8)
Make Object Sphere 2,6,5,5
Texture Object 2,8
Set Object Cull 2,0
Set Object Transparency 2,1
For i = 1 to Limbcount
   if rnd(12)=1
      Instance Object i+2,2
      Glue Object To Limb i+2,1,i
   Endif
Next i
limb=Rnd(Limbcount-2)+2
Glue Object To Limb 2,1,limb
Sync


Do
   Turn Object Right 1,.2
   Sync
Loop

Function Fractal_Limb(Obj,Parent,Depth)
   If Depth>=5
      ExitFunction
   Endif
   Inc Limbcount
   Make object from Limb 101,Obj,Parent
   y#=Object Size Y(101)
   e=Rnd(15)
   Scale object 101,60+e,60+e,60+e
   Make Mesh From Object 101,101
   Delete Object 101
   Add Limb Obj,LimbCount,101
   Offset Limb Obj,LimbCount,0,Rnd(y#/3.0)+2*y#/3.0,0
   Link Limb Obj,Parent,LimbCount
   Texture Limb Obj,LimbCount,Obj
   P2=Limbcount
   i=1
   For i = 1 to rnd(2)+2
      Fractal_Limb(obj,P2,Depth+1)
   Next i
   Rotate Limb 1,P2,rnd(160)-80,rnd(360),0
   `Sync
Endfunction

Function Make_Branch(obj)
   Ink RGB(128,10,0),0
   Box 0,0,64,64
   Get Image obj,0,0,63,63,1
   Make Object Triangle obj,1,0,0,0,10,.5,-1,0,0
   Make Mesh From Object obj,obj
   Add Limb Obj,1,obj
   Rotate Limb Obj,1,0,180,0
   Add Limb Obj,2,obj
   Rotate Limb Obj,2,180,90,0
   Offset Limb Obj,2,0,10,0
   Add Limb Obj,3,obj
   Rotate Limb Obj,3,180,-90,0
   Offset Limb Obj,3,0,10,0
   Make Mesh From Object Obj,Obj
   Delete Object Obj
   Make Object Obj,obj,obj
   Set Object Cull Obj,0
Endfunction

Function Leaf(img)
   Ink Rgb(0,0,0),0
   Box 0,0,20,20
   Ink Rgb(0,200,0),0
   For y=1 to 19
      x=cos(y*9)*19
      Line 10-x,y,10+x,y
   Next y
   Get Image img,0,0,20,20,1
Endfunction

Function Leaves(img)
   Leaf(7)
   Ink Rgb(0,0,0),0
   Box 0,0,256,256
   For i = 1 to 70
      Sprite 7,rnd(255),Rnd(255),7
      Rotate Sprite 7,rnd(360)
      Paste Sprite 7,rnd(255),Rnd(255)
   Next i
   Get Image img,0,0,255,255,1
   Delete Sprite 7
Endfunction